Перенос документов Установка цен номенклатуры с наполнением характеристиками в базе получателе

Перенос документов Установка цен номенклатуры из УТ 10.2 (платформа 8.1) в розница 2.2 (платформа 8.3). Задача осложнялась тем, что в УТ док установка цен создавался без характеристик. То есть в процессе переноса каждую номенклатурную позицию нужно было дополнить характеристиками. Характеристики в моем случае это размерный ряд обуви, потому характеристика не влияла на цену. В дополнение к характеристике в переносе нуждались также и штрихкоды.

Статья подразумевает знание стандартных мероприятий по выгрузке метаданных из баз источника и получателя. Конвертация данных версии 2.

Посмотрев документацию стало понятно, что реализовать данное мероприятие можно 2 способами:

  1. Используя процедуру ВыгрузитьПоПравилу()
  2. Используя событие «перед обработкой» коллекции (таб. части) «товары»

Выгрузить по правилу можно использовать только в ПВД (в моем случае) и после вызова данной процедуры нужно установить Отказ = Истина; иначе отработает стандартный механизм выгрузки и данные выгрузятся повторно.

В событии «перед обработкой» использовал переменную конвертации данных «КоллекцияОбъектов». Вот выдержка из справки:

КоллекцияОбъектов — Неопределено. Если в теле обработчика определить коллекцию (присвоив данной переменной значение, например, описывающее табличную часть или набор движений, например, типа ТаблицаЗначений), то стандартное получение коллекции выполняться не будет.

Другими словами дополнив характеристиками номенклатурные позиции и присвоив переменной «КоллекцияОбъектов» мы получим желаемое.

Нужно сказать, что к моменту выгрузки цен номенклатура и ее характеристики уже должны быть перенесены в базу получатель. В моем случае номенклатура с характеристиками переносилась в этих же правилах обмена совместно с планом обмена, дабы не гонять данные в пустую.

Перейдем снимку правил:

Для ПКО источника в событии «Перед выгрузкой» установлена отсечка не проведенных документов:

Отказ = Не Источник.Проведен;

Далее в том же ПКО есть строчка для проведения перенесенного документа:

РежимЗаписи = "Проведение";

С ПКО все понятно, ничего сложного нет. Переходим к конвертации свойств:

Все просто источник -> получатель, только в группе товары описан обработчик события «перед обработкой». Вот его содержимое:

//при создании док. установка цен не заполняется характеристика
//однако характеристика нужна в рознице, иначе цены не найдутся
//запрос влевую объединяет характеристики к номенклатуре
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
               |	&Документ КАК Ссылка,
               |	УстановкаЦенНоменклатурыТовары.НомерСтроки,
               |	УстановкаЦенНоменклатурыТовары.Номенклатура,
               |	УстановкаЦенНоменклатурыТовары.ХарактеристикаНоменклатуры,
               |	УстановкаЦенНоменклатурыТовары.Цена,
               |	УстановкаЦенНоменклатурыТовары.Валюта,
               |	УстановкаЦенНоменклатурыТовары.ЕдиницаИзмерения,
               |	УстановкаЦенНоменклатурыТовары.ПроцентСкидкиНаценки,
               |	УстановкаЦенНоменклатурыТовары.ТипЦен,
               |	УстановкаЦенНоменклатурыТовары.ИндексСтрокиТаблицыЦен
               |ПОМЕСТИТЬ ВТ
               |ИЗ
               |	&ТабТовары КАК УстановкаЦенНоменклатурыТовары
               |;
               |
               |////////////////////////////////////////////////////////////////////////////////
               |ВЫБРАТЬ
               |	ВТ.Ссылка,
               |	ВТ.Номенклатура,
               |	ХарактеристикиНоменклатуры.Ссылка КАК ХарактеристикаНоменклатуры,
               |	ВТ.Цена,
               |	ВТ.Валюта,
               |	ВТ.ЕдиницаИзмерения,
               |	ВТ.ПроцентСкидкиНаценки,
               |	ВТ.ТипЦен
               |ИЗ
               |	ВТ КАК ВТ
               |		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ХарактеристикиНоменклатуры КАК ХарактеристикиНоменклатуры
               |		ПО ВТ.Номенклатура = ХарактеристикиНоменклатуры.Владелец
               |;
               |
               |////////////////////////////////////////////////////////////////////////////////
               |УНИЧТОЖИТЬ ВТ";

Запрос.УстановитьПараметр("ТабТовары", Источник.Товары);
Запрос.УстановитьПараметр("Документ", Источник.Ссылка);

Результат = Запрос.Выполнить();
Если Не Результат.Пустой() Тогда
	КоллекцияОбъектов = Результат.Выгрузить();
КонецЕсли;

Простой запрос расширяет строки номенклатуры из таб. части товары характеристиками. Напомню, что характеристики уже должны существовать в базе получателя.

Документы установки цен переносятся один к одному, только в получателе строк больше (в соответствии с характеристиками).

Вот такой прием позволяет обойтись без вызова процедуры «ВыгрузитьПоПравилу()». Далее хочу описать выгрузку штрихкодов упомянутую в начале. Вернемся в ПВД выгрузки установки цен и заглянем в событие «ПослеВыгрузки». Вот его содержимое:

//Выгрузка штрих кодов
Если Объект.Проведен Тогда
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	Штрихкоды.ТипШтрихкода,
	|	Штрихкоды.Штрихкод,
	|	Штрихкоды.Владелец,
	|	Штрихкоды.ЕдиницаИзмерения,
	|	Штрихкоды.ХарактеристикаНоменклатуры,
	|	Штрихкоды.СерияНоменклатуры,
	|	Штрихкоды.Качество
	|ИЗ
	|	РегистрСведений.Штрихкоды КАК Штрихкоды
	|ГДЕ
	|	Штрихкоды.Владелец В
	|			(ВЫБРАТЬ
	|				УстановкаЦенНоменклатурыТовары.Номенклатура
	|			ИЗ
	|				Document.УстановкаЦенНоменклатуры.Товары КАК УстановкаЦенНоменклатурыТовары
	|			ГДЕ
	|				УстановкаЦенНоменклатурыТовары.Ссылка = &Документ
	|			СГРУППИРОВАТЬ ПО
	|						УстановкаЦенНоменклатурыТовары.Номенклатура)";
	
	Запрос.УстановитьПараметр("Документ", Объект);
	
	Результат = Запрос.Выполнить();
	Выборка = Результат.Выбрать();
	
	Пока Выборка.Следующий() Цикл
		Пакет = Новый Структура;
		Пакет.Вставить("Активность", Истина);
		Пакет.Вставить("ТипШтрихкода", Выборка.ТипШтрихкода);
		Пакет.Вставить("Штрихкод", Выборка.Штрихкод);
		Пакет.Вставить("Владелец", Выборка.Владелец);
		Пакет.Вставить("ЕдиницаИзмерения", Выборка.ЕдиницаИзмерения);
		Пакет.Вставить("Характеристика", Выборка.ХарактеристикаНоменклатуры);
		Пакет.Вставить("СерияНоменклатуры", Выборка.СерияНоменклатуры);
		Пакет.Вставить("Качество", Выборка.Качество);
		
	    ВыгрузитьПоПравилу(,,Пакет,,"Штрихкоды");
	КонецЦикла;	
КонецЕсли;

Это как раз случай применения механизма «ВыгрузитьПоПравилу()». Сам алгоритм весьма простой. Собираем все штрихкоды номенклатурных позиций документа установка цен. Далее формируем структуру описывающую структуру ПКО «штрихкоды»

Хочу отметить, что у этого правила я установил флаг «Получить из входящих данных» без указания источника.

Конвертация данных, по моему мнению, замечательная вещь. Нужно только не бояться её и осваивать. В чем я вам и желаю успехов!